要把博客发布的文章, 弄成年月日的样式,比如20080615**.html, 可是自己在后台不会修改， 在论坛搜到了一篇原创文章
[原创]新建文章时－静态文件名－以当前日期＋时间自动生成的代码
http://bbs.rainbowsoft.org/viewt ... C%CE%C4%BC%FE%C3%FB
自己按照她的方法做了之后效果不错，可是单月份的时候，只显示一个数字，（估计单日的时候也会）既比如今天就是2008615XXXXXX.html 可是 我希望了是20080615XXXXXX.html
于是把她的函数就替换掉了
<!-- 格式化时间-->
<%Function Format_Time(s_Time, n_Flag)
Dim y, m, d, h, mi, s
Format_Time = ""
If IsDate(s_Time) = False Then Exit Function
y = cstr(year(s_Time))
m = cstr(month(s_Time))
If len(m) = 1 Then m = "0" & m
d = cstr(day(s_Time))
If len(d) = 1 Then d = "0" & d
h = cstr(hour(s_Time))
If len(h) = 1 Then h = "0" & h
mi = cstr(minute(s_Time))
If len(mi) = 1 Then mi = "0" & mi
s = cstr(second(s_Time))
If len(s) = 1 Then s = "0" & s
Select Case n_Flag
Case 1
' yyyy-mm-dd hh:mm:ss
Format_Time = y & "-" & m & "-" & d & " " & h & ":" & mi & ":" & s
Case 2
' yyyymmdd
Format_Time = y & m & d & h & mi & s
End Select
End Function
%>
<a href="#" onclick="document.edit.edtAlias.value='<%= Format_Time(now(),2)%>'"><strong>[文件名取为当前日期＋时间]</strong></a>
还是加在原来的位置<%If CheckRights("FileSnd") Then%>之后
这个函数的初始也给大家 可以自己修改做其他用处
'**************************************************
'函数说明：[格式化时间(显示)]
'函数名：Format_Time
'作 用：格式化时间(显示)
'参 数：s_Time ---- 时间变量
'参 数：n_Flag ---- 时间样式类型代码
' 1:"yyyy-mm-dd hh:mm:ss"
' 2:"yyyy-mm-dd"
' 3:"hh:mm:ss"
' 4:"yyyy年mm月dd日"
' 5:"yyyymmdd"
' 6:"MM/DD"
'返回值：返回格式化后时间
'示例：response.write Format_Time(now(),4)
'**************************************************
Public Function Format_Time(s_Time, n_Flag)
Dim y, m, d, h, mi, s
Format_Time = ""
If IsDate(s_Time) = False Then Exit Function
y = cstr(year(s_Time))
m = cstr(month(s_Time))
If len(m) = 1 Then m = "0" & m
d = cstr(day(s_Time))
If len(d) = 1 Then d = "0" & d
h = cstr(hour(s_Time))
If len(h) = 1 Then h = "0" & h
mi = cstr(minute(s_Time))
If len(mi) = 1 Then mi = "0" & mi
s = cstr(second(s_Time))
If len(s) = 1 Then s = "0" & s
Select Case n_Flag
Case 1
' yyyy-mm-dd hh:mm:ss
Format_Time = y & "-" & m & "-" & d & " " & h & ":" & mi & ":" & s
Case 2
' yyyy-mm-dd
Format_Time = y & "-" & m & "-" & d
Case 3
' hh:mm:ss
Format_Time = h & ":" & mi & ":" & s
Case 4
' yyyy年mm月dd日
Format_Time = y & "年" & m & "月" & d & "日"
Case 5
' yyyymmdd
Format_Time = y & m & d
Case 6
'mm/dd
Format_Time = m & "/" & d
case 7
Format_Time = m & "/" & d & "/" & right(y,2)
End Select
End Function
